QSVEnc for Arch Linux

PKGBUILD

_UpstreamPkgName=QSVEnc
pkgname=${_UpstreamPkgName,,}
pkgver=7.58
pkgrel=1
pkgdesc="Intel Quick Sync Video based command line encoder"
arch=('x86_64')
url="https://github.com/rigaya/$_UpstreamPkgName"
license=('MIT')
depends=(
    'intel-media-driver'
    'intel-compute-runtime'
    'onevpl-intel-gpu'
    'libva'
    libavcodec.so
    libavformat.so
    libavfilter.so
    libavutil.so
    libswresample.so
    libavdevice.so
    libass.so
)
optdepends=(
    'avisynth: avs file support'
    'vapoursynth: vpy file support'
)
makedepends=(
    'cmake'
    'git'
    'opencl-headers'
    'onevpl'
)
source=("git+${url}.git#tag=${pkgver}")
sha256sums=('SKIP')

prepare() {
    cd $_UpstreamPkgName
    git submodule init
    git -c protocol.file.allow=always submodule update
}

build() {
    cd $_UpstreamPkgName
    ./configure --prefix=/usr
    make
}

package() {
    cd $_UpstreamPkgName
    make PREFIX="$pkgdir/usr" install
    # since it is MIT we need to install a license file
    install -Dm 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" license.txt
    # install documentation
    install -Dm 644 -t "${pkgdir}/usr/share/doc/${pkgname}" QSVEncC_Options.* Readme.*
}