Conditional Dev Mode Symlinks for Nix Config

dev-link.nix

{ config, lib, inputs, ... }:

{
  options.dev = {
    nixConfigPathForDevLinks = lib.mkOption {
      type = lib.types.nullOr lib.types.str;
      default = null;
      description = ''
        When set, enables development mode and symlinks files directly from the nix-config repo.
        Set to the path of your nix-config repository (e.g., "/home/manu/dev/nix-config").
        When null, files are deployed normally.
      '';
    };
  };

  config = 
    let
      devMode = config.dev.nixConfigPathForDevLinks != null;
      flakeRoot = toString inputs.self;
    in
    {
      lib.file.mkSymlinkInDevMode = pathArg:
        if devMode
        then 
          let 
            abs = toString pathArg;
            relativePath = lib.strings.removePrefix "${flakeRoot}/" abs;
          in
            config.lib.file.mkOutOfStoreSymlink "${config.dev.nixConfigPathForDevLinks}/${relativePath}"
        else pathArg;
      
      # Helper that returns { source = ...; executable = ...; } for executable files
      lib.file.mkExecSymlinkInDevMode = pathArg:
        if devMode
        then 
          let 
            abs = toString pathArg;
            relativePath = lib.strings.removePrefix "${flakeRoot}/" abs;
          in
            {
              source = config.lib.file.mkOutOfStoreSymlink "${config.dev.nixConfigPathForDevLinks}/${relativePath}";
            }
        else {
          source = pathArg;
          executable = true;
        };
      
      # Export devMode for use in configs
      lib.file.isDevMode = devMode;
    };
}