PKGBUILD for tsukimi, allow custom Danmaku appid and app secret

PKGBUILD

_pkgname="tsukimi"
pkgname="${_pkgname}-git"
pkgver=25.5.0.r1334.g444ed0
pkgrel=1
pkgdesc='A simple third-party Emby client'
arch=('x86_64')
url="https://github.com/tsukinaha/tsukimi"
license=('GPL-3.0-or-later')
provides=('tsukimi')
conflicts=('tsukimi')
depends=(
    'mpv'
    'ffmpeg'
    'libadwaita'
    'gstreamer'
    'gtk4'
)
makedepends=(
    'cargo-nightly'
    'git'
    'meson'
)
source=(
    git+https://github.com/sukanka/tsukimi.git
)
sha256sums=(
    'SKIP'
)
options=(!lto)

pkgver() {
    cd "${_pkgname}"
    echo $(grep '^version =' Cargo.toml | head -n1 | cut -d\" -f2).r$(git rev-list --count HEAD).g$(git describe --long --tags --abbrev=7 | tail -c 7)
}
prepare() {
    cd "${srcdir}/${_pkgname}"
    sed -i 's|tsukinaha/dandanapi|sukanka/dandanapi|g' Cargo.toml
}

build() {
    sed -i 's|tsukinaha/dandanapi|sukanka/dandanapi|g' "${srcdir}/${_pkgname}"/Cargo.toml
    arch-meson "${srcdir}/${_pkgname}" build
    meson compile -C build
}

package() {
    meson install -C build --no-rebuild --destdir "$pkgdir"
}