bnf.bnf

bnf.bnf

wspace ::= '\t' | '\n' | '\v' | '\f' | '\r' | ' '.
wspaces ::= <wspace>
          | <wspace> <wspaces>.
ospaces ::=
          | <wspaces>.
char-constant ::= '\'' [^'] '\''
                | '\'' '\\' <char> '\''.
range-char ::= [^]].
ranges ::= | <range-char> <ranges>. 
range-constant ::= '[' <ranges> ']
                 | '[' '^' <ranges> ']
                 | '[' ']' <ranges> ']
                 | '[' '^' ']' <ranges> '].
string-constant-char ::= [^"]
                       | '\\' <char>.
string-constant-chars ::= | <string-constant-char> <string-constant-chars>.
string-constant ::= '"' <string-constant-chars> '"'.
identifier-char ::= [^][ ^<>'":=\|].
identifier ::= <identifier-char>
             | <identifier-char> <identifier>.
reference ::= '<' <identifier> '>'.
bnf-element ::= <char-constant>
              | <string-constant>
              | <range-constant>
              | <reference>.
bnf-branch ::= <ospaces>
             | <ospaces> <bnf-element> <bnf-branch>.
bnf-branches ::= <bnf-branch>
               | <bnf-branch> '|' <bnf-branches>.
bnf-definition ::= <identifier> <ospaces> "::=" <bnf-branches> '.'.
bnf ::= <ospaces>
      | <ospaces> <bnf-definition> <bnf>.