fruitmath.jl

abstract type Countable{sym} end

Base.show(io::IO, x::Countable{sym}) where sym = print(io, x.n == 1 ? "$sym" : "$(x.n)$sym")
getsym(x::Countable{sym}) where sym = sym

Base.:*(n::Integer, x::Countable) = typeof(x)(n * x.n)

Base.:+(a::Countable, b::Countable) = error("Can't add $(getsym(a))s and $((getsym(b)))s")
Base.:+(a::T, b::T) where {T<:Countable} = T(a.n + b.n)

Base.:<(a::Countable, b::Countable) = error("Can't compare $(getsym(a))s with $(getsym(b))s")
Base.:<(a::T, b::T) where {T<:Countable} = a.n < b.n


struct Fruit{sym} <: Countable{sym}
    n::Int
end

struct Animals{sym} <: Countable{sym}
    n::Int
end

Base.:+(eaters::Animals, fruit::Fruit) = typeof(fruit)(fruit.n - eaters.n)


const 🍎 = Fruit{:🍎}(1)
const 🍐 = Fruit{:🍐}(1)
const 🍌 = Fruit{:🍌}(1)

const 😮 = Animals{:😮}(1)
const 🐒 = Animals{:🐒}(1)
const 🐄 = Animals{:🐄}(1)

Base.:+(eaters::Animals{:🐒}, fruit::Fruit{:🍌}) = typeof(fruit)(fruit.n - 2 * eaters.n)

function Base.:+(eaters::Animals{:🐄}, fruit::Fruit)
    @warn "Moooooo!"
    return fruit
end



typeof(🍎) == typeof(🍐)


🍎 + 2🍎 + 3🍎

2🍎 < 3🍎

2🍎 + 3🍐

🍎 < 🍐

4😮 + 6🍎

2😮 + 6🍌
2🐒 + 6🍌
2🐄 + 6🍌