Advent of Code 2025 day 6

aoc06

#!/usr/bin/env raku
use v6.d;
$*OUT.out-buffer = False;   # Autoflush

# Advent of Code 2025 day 6 -- https://adventofcode.com/2025/day/6

unit sub MAIN(IO() $inputfile where *.f = 'aoc06.input', Bool :v(:$verbose) = False);

# Apply the operator (+ or *) given as the last element to the remaining terms
sub calculate(@problem is copy) is nodal
{
    given @problem.pop {
        say '# ', @problem.join(" $_ ") if $verbose;
        when '+' { return [+] @problem; }
        when '*' { return [*] @problem; }
    }
}

# Extract operator from (first) term in input and append as last element
sub extract-operator(@input) is nodal
{
    my $oper;
    gather for @input -> $term {
        if $term ~~ / (\d+) \s* (<[+*]>?) / {
            take +$0;
            $oper = ~$1 if ~$1;
        }
        LAST { take $oper }
    }
}

# List equivalent of comb: return sublists of consecutive matching elements
sub lcomb(@list, $match)
{
    my @ret;
    my $row = 0;
    for @list -> $elem {
        if $elem ~~ $match {
            @ret[$row].push($elem);
        }
        else {
            $row++;
        }
    }
    return @ret;
}

my @input1 = [Z] $inputfile.lines».words;
if $verbose { say '> ', $_ for @input1 }
say "Part one: ", @input1».&calculate.sum;

my @input2 = ([Z~] $inputfile.lines».comb).&lcomb(/ \S /)».&extract-operator;
if $verbose { say '> ', $_ for @input2 }
say "Part two: ", @input2».&calculate.sum;