Diff port dependencies

deps_diff.tcl

#! /usr/bin/env port-tclsh

package require macports
package require registry2
mportinit

set portname [lindex $argv 0]

set regref [lindex [registry::entry installed $portname] 0]
set requested_variants [$regref requested_variants]
set requested_variations [macports::_variants_to_variations $requested_variants]

set installed_mport [mportopen_installed [$regref name] [$regref version] [$regref revision] [$regref variants] {}]
set installed_portinfo [mportinfo $installed_mport]

lassign [mportlookup $portname] portname cur_portinfo
set cur_mport [mportopen [dict get $cur_portinfo porturl] [dict create subport $portname] $requested_variations]

set cur_portinfo [mportinfo $cur_mport]

puts "Port name: $portname\n"
puts "Installed variants: [dict get $installed_portinfo canonical_active_variants]"
puts "New variants:       [dict get $cur_portinfo canonical_active_variants]\n"

foreach deptype $macports::all_dep_types {
    set installed_deps [expr {[dict exists $installed_portinfo $deptype] ? [dict get $installed_portinfo $deptype] : {}}]
    set cur_deps [expr {[dict exists $cur_portinfo $deptype] ? [dict get $cur_portinfo $deptype] : {}}]
    if {$installed_deps ne $cur_deps} {
        puts "Installed ${deptype}: $installed_deps"
        puts "New ${deptype}:       $cur_deps"
        foreach dep $cur_deps {
            if {$dep ni $installed_deps} {
                puts "Added to ${deptype}: $dep"
            }
        }
        foreach dep $installed_deps {
            if {$dep ni $cur_deps} {
                puts "Removed from ${deptype}: $dep"
            }
        }
    }
}