PELLA gold coins and images

pella_gold.sparql

PREFIX crm:  <http://www.cidoc-crm.org/cidoc-crm/>
PREFIX dcterms:  <http://purl.org/dc/terms/>
PREFIX dcmitype:  <http://purl.org/dc/dcmitype/>
PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
PREFIX geo:  <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX nm:  <http://nomisma.org/id/>
PREFIX nmo:  <http://nomisma.org/ontology#>
PREFIX org:  <http://www.w3.org/ns/org#>
PREFIX rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:  <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos:  <http://www.w3.org/2004/02/skos/core#>
PREFIX xsd:  <http://www.w3.org/2001/XMLSchema#>

SELECT ?coin ?type ?mint ?denomination ?weight ?diameter ?axis ?hoard ?obvImage ?revImage ?comImage WHERE {
  ?type dcterms:source nm:price1991 ;
        a nmo:TypeSeriesItem ;
        nmo:hasMaterial nm:av ;
        nmo:hasMint ?mint ;
        nmo:hasDenomination ?denomination .
  ?coin a nmo:NumismaticObject ;
          nmo:hasTypeSeriesItem ?type .
  OPTIONAL {?coin nmo:hasWeight ?weight }
  OPTIONAL {?coin nmo:hasDiameter ?diameter }
  OPTIONAL {?coin nmo:hasAxis ?axis }
  OPTIONAL {?coin dcterms:isPartOf ?hoard }
  OPTIONAL {?coin nmo:hasObverse/foaf:depiction ?obvImage ;
           nmo:hasReverse/foaf:depiction ?revImage}
  OPTIONAL {?coin foaf:depiction ?comImage }
}