Interview Noter AppleScript

interview-noter.scpt

# interview-noter.scpt
# Version:  1.0 
#
# A script for taking timestamped notes from interviews.
#
# Originally by Jason Snell as [podcast-noter.scpt](https://gist.github.com/jasonsnell/9b95468474d6cc864d4feb6e2a5ca9cf).
#
# Updated by Anthony Arblaster on 04 November 2025.
#    – Mastodon: https://mastodonapp.uk/@aarblaster
#    – GitHub: https://github.com/aarblaster
#

use AppleScript version "2.4" -- Yosemite (10.10) or later
use scripting additions

on run argv
	try
		set theNote to (item 1 of argv)
	on error
		set theNote to ""
	end try
	
	set theSavePath to "/myfilepath/" # <-- Update this to your path!
	
	set theDatematch to (do shell script "date '+%Y-%m-%d'")
	
	set theLatestMatch to date "Tuesday, 18 May 2010 at 13:10:08"
	
	try
		tell application "Finder"
			set theMatches to (every file of (POSIX file theSavePath as alias) whose name contains theDatematch)
			set theWinner to item 1 of theMatches
			repeat with i from 1 to (count of items in theMatches)
				set theMatched to creation date of item i of theMatches
				if theMatched > theLatestMatch then
					set theLatestMatch to theMatched
					set theWinner to item i of theMatches
				end if
			end repeat
			
			set theStartTime to (creation date of theWinner)
			
		end tell
	on error
		display notification "No session found."
		return
		
	end try
	
	set theOffset to ((current date) - theStartTime)
	
	set theTimeStamp to secondstoHMS from theOffset
	
	if (theNote as text) = "" then
		set theStamper to theTimeStamp
	else
		set theStamper to (theTimeStamp & " - " & (theNote as text))
	end if
	
	set theSafeDatematch to (do shell script "date -j -f '%A, %e %B %Y at %H:%M:%S' '" & theStartTime & "' '+%Y-%m-%d'")
	
	do shell script ("echo " & quoted form of theStamper & " >> " & quoted form of (theSavePath & theSafeDatematch & " - Interview Notes" & ".txt"))
	
end run

on secondstoHMS from theSeconds
	tell theSeconds to return my pad(it div hours) & ":" & my pad(it mod hours div minutes) & ":" & my pad(it mod minutes)
end secondstoHMS

on pad(v)
	return text -2 thru -1 of (v + 100 as text)
end pad

I posted about how I'm using this script at phd.anthonyarblaster.com