Improved PKGBUILD for zix-git

gitignore

pkg/
src/
zix-git-*.pkg.tar.*
zix/

PKGBUILD-zix-git

# Maintainer: Ethan Kerrick <kerrickethan -at- gmail -dot- com>
# Contributor: Christopher Arndt <aur -at- chrisarndt -dot -de>

_pkgname=zix
pkgname=$_pkgname-git
pkgver=0.8.1.r642.e1cbd66
pkgrel=1
pkgdesc="A lightweight C library of portability wrappers and data structures"
arch=(x86_64)
url='https://github.com/drobilla/zix'
license=(ISC)
depends=(glibc)
makedepends=(git meson)
provides=($_pkgname "$_pkgname=${pkgver//.r*/}")
conflicts=($_pkgname)
source=("$_pkgname::git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd $_pkgname
  local ver=$(grep -E "^\s+version: '[0-9]+\.[0-9]+\.[0-9]+'" meson.build | cut -d "'" -f 2)
  echo $ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

build() {
  arch-meson $_pkgname $_pkgname-build
  meson compile -C $_pkgname-build
}

package() {
  provides+=(libzix-0.so)
  meson install -C $_pkgname-build --destdir "$pkgdir"
  # license
  install -vDm 644 $_pkgname/COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
  # documentation
  mv -v "$pkgdir"/usr/share/doc/{$_pkgname-0,$pkgname}
  install -vDm 644 $_pkgname/{NEWS,README.md} -t "$pkgdir"/usr/share/doc/$pkgname
}