fossa with gradle

apply plugin: 'cpp'
apply plugin: 'c'

model {
    components {

        /**
         * Definition of the main executable
         */
        main(NativeExecutableSpec) {
            sources {
                cpp {
                    source {
                        srcDir 'src/main'
                        include '**/*.cpp'
                    }
                }
            }
            binaries.all {
                lib library: 'fossa', linkage: 'static'

                if (toolChain in VisualCpp) {
                    cppCompiler.args '/W4', '/WX' // enable all warnings
                    cppCompiler.args '/EHsc' // enable exceptions
                }

                if (toolChain in Clang) {
                    cppCompiler.args '-std=c++11' // enable c++11
                }
            }
        }

        /**
         * Definition of the FOSSA library
         */
        fossa(NativeLibrarySpec) {
            sources {
                c {
                    source {
                        srcDir 'src/fossa'
                        include '**/*.c'
                    }
                    exportedHeaders {
                        srcDir 'src/fossa'
                    }
                }
            }
            binaries.all {
                cCompiler.define 'NS_ENABLE_THREADS'
            }
        }
    }
}