Crystal script to generate local documentation for specified dependencies

docgen.cr

require "file_utils"
require "wait_group"

# {name, link, refname}
DEPS = [
  {"kemal", "https://github.com/kemalcr/kemal", "master"},
  {"db", "https://github.com/crystal-lang/crystal-db", "master"},
  {"sqlite3", "https://github.com/crystal-lang/crystal-sqlite3", "master"},
  {"radix", "https://github.com/luislavena/radix", "master"},
  {"backtracer", "https://github.com/Sija/backtracer.cr", "master"},
  {"exception_page", "https://github.com/crystal-loot/exception_page", "master"},
]

def docgen(name, link, refname)
  lib_dir = "lib/#{name}"

  unless Dir.exists? lib_dir
    puts "Dir not found: #{lib_dir}"
    return
  end

  url = "#{link}/blob/%{refname}/%{path}#L%{line}"
  args = ["docs", "--source-url-pattern=#{url}", "--source-refname=#{refname}"]

  if Process.run("crystal", args, chdir: lib_dir).success?
    puts "#{name} succeded"
  else
    puts "#{name} failed"
  end
end

wg = WaitGroup.new(DEPS.size)

DEPS.each do |(name, link, refname)|
  spawn do
    docgen(name, link, refname)
  ensure
    wg.done
  end
end

wg.wait